home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
EnigmA Amiga Run 1997 May
/
EnigmA AMIGA RUN 18 (1997)(G.R. Edizioni)(IT)[!][issue 1997-05][EAR-CD II].iso
/
programs
/
cdindex
/
creaindice
< prev
next >
Wrap
Text File
|
1997-04-03
|
2KB
|
71 lines
setenv title CreaIndiceCD 2.0
setenv body1 CreaIndiceCD v2.0 ©1997 by Diego Nova*n*n
setenv body2 Questo programma ti permette di creare*n
setenv body3 un file .INDICE di un CD-ROM, nel formato*n
setenv body4 leggibile da CDIndexer 2.0® e CDFind 2.0®*n
requestchoice >env:risp "$title" "$body1 $body2 $body3 $body4" "Continua|Annulla"
IF $risp VAL EQ 0
skip abort
ENDIF
setenv title CreaIndiceCD 2.0
setenv body1 Dopo questa schermata ti verrà presentato*n
setenv body2 un requester in cui dovrai selezionare la*n
setenv body3 destinazione per il file .INDICE cha verrà*n
setenv body4 generato.*n
requestchoice >env:risp "$title" "$body1 $body2 $body3 $body4" "Continua|Annulla"
IF $risp VAL EQ 0
skip abort
ENDIF
requestfile >env:dest DRAWER "SYS:" PATTERN "~(#?.info)" TITLE "Seleziona la destinazione del file INDICE" DRAWERSONLY
IF WARN
skip abort
ENDIF
setenv title CreaIndiceCD 2.0
setenv body1 Ora ti verrà richiesto di scegliere la*n
setenv body2 directory (su CD-ROM) da cui partire per*n
setenv body3 creare l'indice.*n
requestchoice >env:risp "$title" "$body1 $body2 $body3" "Continua|Annulla"
IF $risp VAL EQ 0
skip abort
ENDIF
requestfile >env:sorg DRAWER "SYS:" PATTERN "~(#?.info)" TITLE "Seleziona la directory sorgente" DRAWERSONLY
IF WARN
skip abort
ENDIF
cd $sorg
list >RAM:T/INDICEFILES.TEMP ALL ~(#?.info) LFORMAT "%E~%P%N~%L"
CreaIndiceCD $sorg $dest >NIL:
lab successful
setenv title CreaIndiceCD 2.0
setenv body1 Indice Creato.*n
setenv body2 Ora puoi utilizzare CDIndexer o CDFind*n
requestchoice >env:cancel "$title" "$body1 $body2" "OK"
skip exit
lab abort
setenv title CreaIndiceCD 2.0
setenv body1 Programma Abbandonato
requestchoice >env:cancel "$title" "$body1" "OK"
lab exit
unsetenv sorg
unsetenv dest
unsetenv title
unsetenv body1
unsetenv body2
unsetenv body3
unsetenv body4
unsetenv cancel
unsetenv risp
unsetenv dir
delete RAM:T/INDICEFILES.TEMP QUIET